Experimental BBS Explossion 3/Experimental BBS Explossion III.iso/games/gscape.zip/SAMPLE.IN3

Text File | 1992-10-07 | 11KB | 688 lines

>REMAR
SAMPLE ADVENTURE-- COMMAND SECTION.
SEE ALSO SAMPLE.IN1 AND SAMPLE.IN2
<

>COMND                       NOTE FOR USERS OF VERSION 3.0:  COMMAS,
* *                          COLONS: AND "QUOTES" ARE NOW ALLOWED IN
IF                           COMMENTS!  "AINT, THAT: GREAT?"
FLAG>
101
50                           If more than 50 moves game is lost.
DO
PRINT                        IMPORTANT NOTE!  Always write down on a
18                           list somewhere (or comment in your code)
END                          exactly what purpose you're assigning to
<                            your flags.  You'll never remember without it!

>COMND
S *
IF
AT
5
FLAG=
2
0
DO
GOTO
1
SHOW
<

>COMND
N *
IF
AT                           If told to go north from lit energy room
6                            then go to central room!
DO
GOTO
1
SHOW
<

>COMND
N *
IF
AT
1
FLAG=                        If energy is not on (fuse fixed)
1                            tell them it is dark and leave them
0                            in room 1
DO
PRINT
15
<

>COMND
DROP *
DO                           Drop any item anywhere
DROP
<

>COMND
N *
IF
AT
1                            If north from center room
FLAG=
1                            and fuse is in and door closed
1
FLAG=
3
0
DO                           go to computer room
GOTO
5
SHOW
<

>COMND
E *
IF
AT
1                            If east from center room
DO                           go to security room
GOTO
4
SHOW
<

>COMND
S *
IF
AT
1                                 If go south from central room
FLAG=                             and energy is on go to room 6
3                                 instead of room 3!
0
FLAG=
1
1
DO
GOTO
6
SHOW
<

>COMND
S *
IF
AT                           If south from center room
1                            go to work room
DO
GOTO
3
SHOW
<

>COMND
W *
IF
AT
1                            If west from center room
DO                           go to observatory
GOTO
2
SHOW
<

>COMND
E *
IF
AT
2
DO                           If east from observatory
GOTO                         go to center room
1
SHOW
<

>COMND
N *
IF
AT
3                            If north from work room
DO                           go to center room
GOTO
1
SHOW
<

>COMND
W *
IF
AT
4
DO                           If west from security room
GOTO                         go to center room
1
SHOW
<

>COMND
SEARCH TELESCOPE
IF
AT                           If key doesn't exist yet and
2                            telescope is searched tell them
NOTEXIST                     they've found a key and move the
1                            key into the room
DO
GRAPH
2
PRINT
2
OBJ
1
2
<

>COMND
SEARCH TELESCOPE
IF
AT                           If they search the telescope after they've
2                            found the key show them stars instead.
PRESENT
1
DO
PRINT
4
<

>COMND
OPEN FUSEBOX
IF
AT                           If they open a closed fusebox
3                            tell them they did so!
FLAG=
3
0
DO
FLAGSET
3
1
PRINT
5
<

>COMND
OPEN FUSEBOX
IF
AT                           If they try to open an open fusebox
3                            tell them they're senile.
FLAG=
3
1
DO
PRINT
6
<

>COMND
SEARCH FUSEBOX
IF                                If the fusebox is searched
AT                                and the fusebox is closed
3                                 and the fusebox hasn't been
FLAG=                             replaced then tell them the
3                                 fusebox is closed.
0
FLAG=
1
0
DO
PRINT
23
<

>COMND
SEARCH FUSEBOX
IF
AT                                If the fusebox is searched
3                                 after the fuse is replaced
FLAG=                             and if the fusebox is still
1                                 open tell them the fusebox
1                                 is open and looking good.
FLAG=
3
1
DO
PRINT
24
<

>COMND
SEARCH FUSEBOX
IF
AT
3
FLAG=
3
1                            If they search an open fusebox
FLAG=
4                            and they haven't seen the blown fuse yet
0
DO
PRINT                        tell them a fuse is blown and
7
FLAGSET
4                            set flag for having seen blown fuse.
1
<

>COMND
SEARCH FUSEBOX
IF
AT
3
FLAG=                        If they search the fusebox
3                            and it is open
1
FLAG=
4                            and they've already seen a fuse is blown
1
DO
PRINT                        tell them so!
8
<

>COMND
SEARCH FUSEBOX
IF                           If they search the fusebox
AT
3
FLAG=                        and the fusebox is open
3
1
FLAG=
1                            and they've fixed the fuse
1
DO
PRINT                        tell them they see an open fusebox.
21
<

>COMND
OPEN BOXES
IF
AT
3
FLAG=
1
0
NOTEXIST
3
DO
PRINT
31
<

>COMND
SEARCH BOXES
IF
AT
3                            If they search boxes and a fuse
NOTEXIST                     does not exist tell them they find
3                            a fuse and move the fuse into the room.
DO
PRINT
9
OBJ
3
3
<

>COMND
SEARCH BOXES
IF                           If they search the boxes but they've
AT                           already picked up the fuse tell
3                            them they're looped.
EXIST
3
302
DO
PRINT
10
<

>COMND
REPLACE FUSE
IF                           If they replace the fuse
AT
3
EXIST                        and they have the fuse to use
3
302
FLAG=
3                            and fusebox is open
1
DO
PRINT
3                            tell them they've fixed the fuse
FLAGSET
1                            set the fuse as being replaced
1
OBJ
3                            and move the fuse to limbo.
301
<

>COMND
REPLACE FUSE
IF
AT                           If they replace the fuse but the
3                            fusebox is closed then tell them
FLAG=                        the fusebox is closed.
3
0
EXIST
3
302
DO
PRINT
23
<

>COMND
REPLACE FUSE                 If they try to replace a fuse they
IF                           don't own let them know.
AT
3
NOTEXIST
3
DO
PRINT
22
<

>COMND
CLOSE FUSEBOX
IF
AT
3                            If they close the fusebox
FLAG=                        and it is open
3
1
FLAG=                        and fuse hasn't been replaced
1
0
DO
FLAGSET
3                            shut the fusebox door
0
PRINT                        and tell them OK you've shut it!
3
<

>COMND
CLOSE FUSEBOX
IF
AT
3                            If try to close the fusebox
FLAG=                        and the fusebox is open
3
1
FLAG=
1                            and the fuse is in place
1
DO
PRINT                        turn the power ON...
11
FLAGSET
3                            and close the fusebox
0
GOTO                         and send them to room 6.
6
<

>COMND
OPEN SAFE
IF
AT
4                            If they open the safe
EXIST
1                            and have the key
302
DO
PRINT                        tell them they've done so and
12
OBJ                          move the disk into the safe.
2
4
<

>COMND
OPEN SAFE
IF
AT                           If they open the safe and
4
NOTEXIST                     the key doesn't exist
1
DO                           tell them they need a key.
GRAPH
4
PRINT
13
<

>COMND
GET DISKETTE
IF
NOTEXIST                     If they get the disk and it's not around
2
DO                           tell them they're screwy.
PRINT
14
<

>COMND
INSERT DISKETTE
IF
AT                           If they insert the disk
5
FLAG=                        and the fuse is replaced
1
1
FLAG=                        and the fusebox door closed
3
0
EXIST
2                            and the disk exists
302
DO
PRINT                        Tell them the place is live with energy
16
FLAGSET
2                            Set the teleport flag on.
1
<

>COMND
EXAM COMPUTER                If exam computer describe.
IF
AT
5
DO
PRINT
33
<

>COMND
INVENTORY *                  List their inventory.
DO
INVEN
<

>COMND
LOOK *
DO                           Show the current location.
SHOW
<

>COMND
END *
DO                           End the game.
END
<

>COMND
QUIT *                       Quit the game.
DO
QUIT
<

>COMND
S *
IF
AT
5
FLAG=                        If they go south and
2                            the teleporter is on
1                            tell them they win the game.
DO
CLS
GRAPH
5
PRINT
1
END
<

>COMND
HELP *                            Display the help screen.
DO
PRINT
19
PRINT
32
<

>COMND
GET TELESCOPE                    If they try to get the
IF                           telescope, tell them it's
DO                           too durn heavy!
PRINT
28
<

>COMND
GET BOXES
IF
AT                           If they try to get the boxes
3                            tell them they rattel.
NOTEXIST
3
DO
PRINT
27
<

>COMND
SEARCH DESK
IF                           If they search the desk tell them
AT                           they are wasting their time.
4
DO
PRINT
20
<

>COMND
OPEN DESK
IF
AT                           Does the same thing as SEARCH DESK
4                            only it works with OPEN DESK instead.
DO                           It's not often this is needed but once
PRINT                        in a while it's the only way to cover
20                           all bases!
<

>COMND
SEARCH SAFE
IF
AT                           If they search the safe and
4                            the diskettes don't exist, tell them
NOTEXIST                     there's a big, heavy safe
2
DO
GRAPH
4
PRINT
25
<

>COMND
SEARCH SAFE
IF                           If they search the safe after
AT                           finding the disk show them the
4                            room (which will also display that
PRESENT                      the disk is now present).
2
DO
SHOW
<

>COMND
SEARCH BLONDE
IF                           If they search the blonde
AT                           tell them they're a pervert.
2
EXIST
1
302
DO
PRINT
29
<

>COMND
GET BLONDE
IF                           If they get the blonde, kill them.
AT
2
DO
PRINT
30
END
<

>COMND
SEARCH KEYHOLE
IF                           If they search the keyhole, tell them
AT                           it's dark.
4
DO
PRINT
26
<

>COMND
SAVE *
DO                           Save the game
SAVE
<

>COMND
LOAD *
DO
LOAD                         Load a previous game
<

>COMND
GET *
DO
OBJ                          STANDARD GET FUNCTION
0
302
INVEN
<


>COMND
* *
DO
PRINT                        If words OK but illogical
17                           tell them about it.
<

>ENDIN